Abfragen für die Tabelle ACSCallRecordingSummary

Informationen zur Verwendung dieser Abfragen im Azure-Portal finden Sie im Log Analytics-Lernprogramm. Informationen zur REST-API finden Sie unter "Abfrage".

Histogramm der Anrufaufnahmedauer

Erzeugt ein Histogramm der Dauer der Anrufaufzeichnung in Sekunden.

ACSCallRecordingSummary
| distinct RecordingId, RecordingLength
// Count call duration bins (60 second intervals)
| summarize duration_counts=count() by bin(RecordingLength, 6000)
| order by RecordingLength asc
| render columnchart with (xcolumn = RecordingLength, title="Recording duration histogram")

Prozentilien der Anrufaufzeichnungsdauer

Berechnet die durchschnittliche Anrufaufzeichnungsdauer in Sekunden sowie die Quantile von 50 %, 90 % und 99 % der Anrufdauer.

ACSCallRecordingSummary
// Get the distinct combinations of RecordingId, RecordingLength
| distinct RecordingId, RecordingLength
// Calculate average and percentiles (50%, 90%, and 99%) of call durations (in seconds)
| summarize avg(RecordingLength), percentiles(RecordingLength, 50, 90, 99)

Verhältnis der Beendigungsgründe bei Anrufaufzeichnungen

Erzeugt ein Kreisdiagramm, das den Anteil der Gründe für das Ende der Anrufaufzeichnungen darstellt.

ACSCallRecordingSummary
// Count distinct calls (dcount(CorrelationId)) per call type
| summarize call_types=dcount(RecordingId) by RecordingEndReason
| render piechart title="Recording End Reason Ratio"

Tägliche Anrufaufzeichnungen

Erstellt ein Histogramm der täglichen Aufzeichnungen aus der letzten Woche.

ACSCallRecordingSummary
// To filter out recordings made over a week ago, uncomment the next line
// | where TimeGenerated > ago(7d)
// Get the distinct combinations of RecordingId and CallStartTime
| distinct RecordingId, TimeGenerated
// Adds a new column with the call start day
| extend day = floor(TimeGenerated, 1d)
// Count the number of calls per day
| summarize event_count=count() by day
| sort by day asc
| render columnchart title="Number of recordings per day"

Stündliche Anrufaufzeichnungen

Produziert ein Histogramm von Aufzeichnungen pro Stunde am letzten Tag.

    ACSCallRecordingSummary
    // To filter out recordings made over a day ago, uncomment the next line
    | where TimeGenerated > ago(1d)
    // Get the distinct combinations of RecordingId and TimeGenerated
    | distinct RecordingId, TimeGenerated
    // Adds a new column with the call start hour
    | extend hour = floor(TimeGenerated, 1h)
    // Count the number of calls per hour
    | summarize event_count=count() by hour
    | sort by hour asc
    | render columnchart title="Number of recordings per hour in last day"

Verhältnis der Betriebsmodi der Anrufaufzeichnung

Erzeugt ein Kreisdiagramm des Anteils der Aufzeichnungsmodi (Inhalts-/Formattypen).

ACSCallRecordingSummary
| summarize count() by ContentType, FormatType
| extend ContentFormat = strcat(ContentType, "/", FormatType)
| project ContentFormat, count_
| render piechart title="Recording by mode (content/format types)"