Hinweis
Für den Zugriff auf diese Seite ist eine Autorisierung erforderlich. Sie können versuchen, sich anzumelden oder das Verzeichnis zu wechseln.
Für den Zugriff auf diese Seite ist eine Autorisierung erforderlich. Sie können versuchen, das Verzeichnis zu wechseln.
Informationen zur Verwendung dieser Abfragen im Azure-Portal finden Sie im Log Analytics-Lernprogramm. Informationen zur REST-API finden Sie unter "Abfrage".
Auflisten eindeutiger SMS-Vorgänge
Gibt alle unterschiedlichen Kombinationen von SMS-Vorgangs- und Versionspaaren zurück.
ACSSMSIncomingOperations
| distinct OperationName, OperationVersion
| limit 100
Berechnen der Perzentile für die Dauer von SMS-Vorgängen
Berechnet das 90., 95. und 99. Perzentil der Laufzeit in Millisekunden für jeden SMS-Vorgang. Sie kann für einen einzelnen Vorgang oder für andere Perzentile angepasst werden.
ACSSMSIncomingOperations
// where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's duration percentiles
| summarize percentiles(DurationMs, 90, 95, 99) by OperationName, OperationVersion // calculate 90th, 95th, and 99th percentiles of each Operation
| limit 100
Top 5 IP-Adressen pro SMS-Vorgang
Rufen Sie für jeden SMS-Vorgang die fünf IP-Adressen ab, die diesen Vorgang am häufigsten aufgerufen haben.
ACSSMSIncomingOperations
// | where OperationName == "<operation>" // This can be uncommented and specified to calculate only a single operation's count
| top-nested of OperationName by dummy=max(0), // For all the Operations...
top-nested 5 of CallerIpAddress by count() // List the IP address that have called that operation the most
| project-away dummy // Remove dummy line from the result set
| limit 100
SMS-Betriebsfehler
Listet jeden SMS-Fehler auf, der nach Aktualität sortiert ist.
ACSSMSIncomingOperations
| where ResultType == "Failed"
| project TimeGenerated, OperationName, OperationVersion, ResultSignature, ResultDescription
| order by TimeGenerated desc
| limit 100
Ergebnisanzahl der SMS-Vorgänge
Zählen Sie für jeden SMS-Vorgang die Typen der zurückgegebenen Ergebnisse.
ACSSMSIncomingOperations
| summarize Count = count() by OperationName, ResultType //, ResultSignature // This can also be uncommented to determine the count of each ResultSignature for each ResultType
| order by OperationName asc, Count desc
| limit 100