Freigeben über

in-Operator

Gilt für: ✅Microsoft Fabric

Filtert einen Datensatzsatz für Daten mit einer Zeichenfolge mit Groß-/Kleinschreibung.

Die folgende Tabelle enthält einen Vergleich der in Operatoren:

Bediener Beschreibung Groß-/Kleinschreibung Beispiel (ergibt true)
in Entspricht einem der Elemente. Ja "abc" in ("123", "345", "abc")
!in Entspricht keinem der Elemente Ja "bca" !in ("123", "345", "abc")
in~ Entspricht einem der Elemente. Nein "Abc" in~ ("123", "345", "abc")
!in~ Entspricht keinem der Elemente Nein "bCa" !in~ ("123", "345", "ABC")

Hinweis

Geschachtelte Arrays werden in einer einzigen Liste von Werten vereinfacht. Beispielsweise wird x in (dynamic([1,[2,3]])) zu x in (1,2,3).

Weitere Informationen zu anderen Operatoren und zur Bestimmung, welcher Operator für Ihre Abfrage am besten geeignet ist, finden Sie unter Datentyp-Zeichenfolgenoperatoren.

Operatoren ohne Beachtung der Groß-/Kleinschreibung werden derzeit nur für ASCII-Text unterstützt. Verwenden Sie für einen Nicht-ASCII-Vergleich die Tolower() -Funktion.

Leistungstipps

Hinweis

Wenn mehr als 128 Suchbegriffe verwendet werden, ist die Suchoptimierung für Textindex deaktiviert, was zu einer verringerten Abfrageleistung führen kann.

Hinweis

Die Leistung hängt vom Typ der Suche und der Struktur der Daten ab. Bewährte Methoden finden Sie unter " Bewährte Methoden für Abfragen".

Syntax

|

Erfahren Sie mehr über Syntaxkonventionen.

Parameter

Name Typ Erforderlich Beschreibung
T string ✔️ Die zu filternde tabellarische Eingabe.
Joch string ✔️ Die Spalte, nach der gefiltert werden soll.
Ausdruck Skalar oder tabellarisch ✔️ Ein Ausdruck, der die Werte angibt, nach denen gesucht werden soll. Jeder Ausdruck kann ein skalarer Wert oder ein tabellarischer Ausdruck sein, der eine Gruppe von Werten erzeugt. Wenn ein tabellarischer Ausdruck mehrere Spalten enthält, wird die erste Spalte verwendet. Die Suche berücksichtigt bis zu 1.000.000 unterschiedliche Werte.

Gibt zurück

Zeilen in T , für die das Prädikat ist true.

Beispiele

Liste der Skalar

Die folgende Abfrage zeigt die Verwendung in mit einer Liste von Skalarwerten.

Ausführen der Abfrage

StormEvents 
| where State in ("FLORIDA", "GEORGIA", "NEW YORK") 
| count

Ausgabe

Anzahl
4775

Dynamisches Array

Die folgende Abfrage zeigt die Verwendung in mit einem dynamischen Array.

Ausführen der Abfrage

let states = dynamic(['FLORIDA', 'ATLANTIC SOUTH', 'GEORGIA']);
StormEvents 
| where State in (states)
| count

Ausgabe

Anzahl
3218

Tabellarischer Ausdruck

Die folgende Abfrage zeigt, wie sie mit einem tabellarischen Ausdruck verwendet in wird.

Ausführen der Abfrage

let Top_5_States = 
    StormEvents
    | summarize count() by State
    | top 5 by count_; 
StormEvents 
| where State in (Top_5_States) 
| count

Dieselbe Abfrage kann mit einer inline tabellarischen Ausdrucksanweisung geschrieben werden.

Ausführen der Abfrage

StormEvents 
| where State in (
    StormEvents
    | summarize count() by State
    | top 5 by count_
    ) 
| count

Ausgabe

Anzahl
14242

Top mit anderem Beispiel

Im folgenden Beispiel werden die fünf obersten Zustände mit Blitzereignissen identifiziert und die iff()-Funktion und in Operator verwendet, um Blitzereignisse nach den fünf obersten Zuständen zu klassifizieren, die nach Statusnamen bezeichnet werden, und alle anderen als "Sonstige" bezeichnet.

Ausführen der Abfrage

let Lightning_By_State = materialize(StormEvents
    | summarize lightning_events = countif(EventType == 'Lightning') by State);
let Top_5_States = Lightning_By_State | top 5 by lightning_events | project State; 
Lightning_By_State
| extend State = iff(State in (Top_5_States), State, "Other")
| summarize sum(lightning_events) by State

Ausgabe

Staat sum_lightning_events
ALABAMA 29
WISCONSIN 31
TEXAS 55
FLORIDA 85
GEORGIEN 106
Andere 415

Verwendung einer statischen Liste, die von einer Funktion zurückgegeben wird

Im folgenden Beispiel werden Ereignisse aus der StormEvents Tabelle basierend auf einer vordefinierten Liste interessanter Zustände zählt. Die interessanten Zustände werden durch die funktion InterestingStates() definiert.

Ausführen der Abfrage

StormEvents 
| where State in (InterestingStates()) 
| count

Ausgabe

Anzahl
4775

In der folgenden Abfrage wird angezeigt, welche Zustände von der funktion InterestingStates() als interessant angesehen werden.

Ausführen der Abfrage

.show function InterestingStates

Ausgabe

Name Parameter Text Ordner DocString
Interessante Staaten () { dynamic(["WASHINGTON", "FLORIDA", "GEORGIA", "NEW YORK"]) }

Verwandte Inhalte

  • Last updated on