Let statement

Applies to: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

A let statement is used to set a variable name equal to an expression or a function, or to create views.

let le istruzioni sono utili per:

• Suddividere un'espressione complessa in più parti, ognuna rappresentata da una variabile.
• Definizione di costanti esterne al corpo della query per la leggibilità.
• Definizione di una variabile una sola volta e uso più volte all'interno di una query.

Se la variabile in precedenza rappresentava un altro valore, ad esempio nelle istruzioni nidificate, si applica l'istruzione più let interna.

Per ottimizzare più usi dell'istruzione let all'interno di una singola query, vedere Ottimizzare le query che usano espressioni denominate.

Sintassi: espressioni scalari o tabulari

let Name=Expression

Learn more about syntax conventions.

Parameters

Sintassi: visualizzazione o funzione

let Name= [view] ([ Parameters ]){FunctionBody}

Learn more about syntax conventions.

Parameters

Examples

Gli esempi di query mostrano la sintassi e l'utilizzo di esempio dell'operatore, dell'istruzione o della funzione.

Definire valori scalari

Nell'esempio seguente viene utilizzata un'istruzione di espressione scalare.

let threshold = 50;
let region = "West";
datatable(Name:string, Score:int, Region:string)
[
    "Alice", 45, "West",
    "Bob", 60, "East",
    "Charlie", 55, "West",
    "Dana", 70, "North"
]
| where Score > threshold and Region == region

Output

Definire espressioni tabulari

Nell'esempio seguente viene associato il nome some number usando la ['name'] notazione e quindi lo usa in un'istruzione di espressione tabulare.

let ['some number'] = 20;
range y from 0 to ['some number'] step 5

Output

Creare una funzione definita dall'utente con calcolo scalare

Questo esempio usa l'istruzione let con argomenti per il calcolo scalare. La query definisce la funzione MultiplyByN per moltiplicare due numeri.

let MultiplyByN = (val:long, n:long) { val * n };
range x from 1 to 5 step 1 
| extend result = MultiplyByN(x, 5)

Output

Creare una funzione definita dall'utente che taglia l'input

Nell'esempio seguente vengono rimossi quelli iniziali e finali dall'input.

let TrimOnes = (s:string) { trim("1", s) };
range x from 10 to 15 step 1 
| extend result = TrimOnes(tostring(x))

Output

Usare più istruzioni let

Questo esempio definisce due istruzioni let in cui un'istruzione (foo2) usa un altro valore (foo1).

let foo1 = (_start:long, _end:long, _step:long) { range x from _start to _end step _step};
let foo2 = (_step:long) { foo1(1, 100, _step)};
foo2(2) | count

Output

Creare una vista o una tabella virtuale

Questo esempio illustra come usare un'istruzione let per creare una view tabella virtuale o .

let Range10 = view () { range MyColumn from 1 to 10 step 1 };
let Range20 = view () { range MyColumn from 1 to 20 step 1 };
search MyColumn == 5

Output

Usare una funzione di materializzazione

La funzione materialize() consente di memorizzare nella cache i risultati della sottoquery durante l'esecuzione della query. Quando si usa la materialize() funzione, i dati vengono memorizzati nella cache e qualsiasi chiamata successiva del risultato usa i dati memorizzati nella cache.

let TotalEventsbyLocation = StormEvents
| summarize TotalCount = count() by Location = BeginLocation;
let materializedScope = StormEvents
| summarize by EventType, Location = EndLocation;
let cachedResult = materialize(materializedScope);
cachedResult
| project EventType, Location
| join kind = inner
(
    cachedResult
    | project EventType, Location
)
on EventType
| where Location != ""
| summarize EventCount = count() by Location
| join kind = inner
    TotalEventsbyLocation
on $left.Location == $right.Location
| project Location, EventCount, TotalCount, Percentage = EventCount * 100.0 / TotalCount

Output

Uso di istruzioni let annidate

Le istruzioni let annidate sono consentite, incluse all'interno di un'espressione di funzione definita dall'utente. Le istruzioni e gli argomenti let si applicano sia nell'ambito corrente che interno del corpo della funzione.

let start_time = ago(5h); 
let end_time = start_time + 2h; 
T | where Time > start_time and Time < end_time | ...

Argomento tabulare con schema

Nell'esempio seguente viene specificato che il parametro T table deve avere una colonna State di tipo string. La tabella T può includere anche altre colonne, ma non è possibile farvi riferimento nella funzione StateState perché non sono dichiarate.

let StateState=(T: (State: string)) { T | extend s_s=strcat(State, State) };
StormEvents
| invoke StateState()
| project State, s_s

Output

Argomento tabulare con carattere jolly

Il parametro T table può avere qualsiasi schema e la funzione CountRecordsInTable funzione funzionerà.

let CountRecordsInTable=(T: (*)) { T | count };
StormEvents | invoke CountRecordsInTable()

Output