Freigeben über

Join-Klausel (Visual Basic)

Kombiniert zwei Auflistungen in einer einzelnen Auflistung. Der Verknüpfungsvorgang basiert auf übereinstimmenden Schlüsseln und verwendet den Equals Operator.

Syntax

Join element In collection _
  [ joinClause _ ]
  [ groupJoinClause ... _ ]
On key1 Equals key2 [ And key3 Equals key4 [... ] ]

Bestandteile

element Erforderlich. Die Steuerelementvariable für die Auflistung, die verknüpft wird.

collection
Erforderlich. Die Sammlung, die mit der auf der linken Seite des Join Operators identifizierten Auflistung kombiniert werden soll. Eine Join Klausel kann in einer anderen Join Klausel oder in einer Group Join Klausel geschachtelt werden.

joinClause
Wahlfrei. Eine oder mehrere zusätzliche Join Klauseln, um die Abfrage weiter zu verfeinern.

groupJoinClause
Wahlfrei. Eine oder mehrere zusätzliche Group Join Klauseln, um die Abfrage weiter zu verfeinern.

key1 Equals key2
Erforderlich. Identifiziert Schlüssel für die Auflistungen, die verknüpft werden. Sie müssen den Equals Operator verwenden, um Schlüssel aus den auflistungen zu vergleichen, die verknüpft werden. Sie können Verknüpfungsbedingungen kombinieren, indem Sie den And Operator verwenden, um mehrere Schlüssel zu identifizieren. key1 muss von der Auflistung auf der linken Seite des Join Operators stammen. key2 muss von der Auflistung auf der rechten Seite des Join Operators stammen.

Die in der Verknüpfungsbedingung verwendeten Schlüssel können Ausdrücke sein, die mehrere Elemente aus der Auflistung enthalten. Jeder Schlüsselausdruck kann jedoch nur Elemente aus der jeweiligen Auflistung enthalten.

Bemerkungen

Die Join Klausel kombiniert zwei Auflistungen basierend auf übereinstimmenden Schlüsselwerten aus den Auflistungen, die verknüpft werden. Die resultierende Auflistung kann eine beliebige Kombination von Werten aus der Auflistung enthalten, die auf der linken Seite des Join Operators und der in der Join Klausel identifizierten Auflistung identifiziert wird. Die Abfrage gibt nur Ergebnisse zurück, für die die vom Equals Operator angegebene Bedingung erfüllt ist. Dies entspricht einem INNER JOIN in SQL.

Sie können mehrere Join Klauseln in einer Abfrage verwenden, um zwei oder mehr Auflistungen mit einer einzelnen Auflistung zu verbinden.

Sie können eine implizite Verknüpfung ausführen, um Sammlungen ohne die Join Klausel zu kombinieren. Fügen Sie dazu mehrere In Klauseln in Ihre From Klausel ein, und geben Sie eine Where Klausel an, die die Schlüssel identifiziert, die Sie für die Verknüpfung verwenden möchten.

Sie können die Group Join Klausel verwenden, um Sammlungen in einer einzigen hierarchischen Auflistung zu kombinieren. Dies ist wie eine LEFT OUTER JOIN in SQL.

Beispiel 1

Im folgenden Codebeispiel wird eine implizite Verknüpfung ausgeführt, um eine Liste von Kunden mit ihren Bestellungen zu kombinieren.

Dim customerIDs() = {"ALFKI", "VICTE", "BLAUS", "TRAIH"}

Dim customerList = From cust In customers, custID In customerIDs
                   Where cust.CustomerID = custID
                   Select cust.CompanyName

For Each companyName In customerList
    Console.WriteLine(companyName)
Next

Beispiel 2

Im folgenden Codebeispiel werden zwei Auflistungen mithilfe der Join Klausel verknüpft.

Imports System.Diagnostics

Public Class JoinSample

    Public Sub ListProcesses()
        Dim processDescriptions As New List(Of ProcessDescription)
        processDescriptions.Add(New ProcessDescription With {
                                    .ProcessName = "explorer",
                                    .Description = "Windows Explorer"})
        processDescriptions.Add(New ProcessDescription With {
                                    .ProcessName = "winlogon",
                                    .Description = "Windows Logon"})
        processDescriptions.Add(New ProcessDescription With {
                                    .ProcessName = "cmd",
                                    .Description = "Command Window"})
        processDescriptions.Add(New ProcessDescription With {
                                    .ProcessName = "iexplore",
                                    .Description = "Internet Explorer"})

        Dim processes = From proc In Process.GetProcesses
                        Join desc In processDescriptions
                          On proc.ProcessName Equals desc.ProcessName
                        Select proc.ProcessName, proc.Id, desc.Description

        For Each proc In processes
            Console.WriteLine("{0} ({1}), {2}",
                              proc.ProcessName, proc.Id, proc.Description)
        Next
    End Sub

End Class

Public Class ProcessDescription
    Public ProcessName As String
    Public Description As String
End Class

In diesem Beispiel wird die Ausgabe ähnlich wie folgt ausgegeben:

winlogon (968), Windows Logon

explorer (2424), File Explorer

cmd (5136), Command Window

Beispiel 3

Im folgenden Codebeispiel werden zwei Auflistungen mithilfe der Join Klausel mit zwei Schlüsselspalten verknüpft.

Imports System.Diagnostics

Public Class JoinSample2

    Public Sub ListProcesses()
        Dim processDescriptions As New List(Of ProcessDescription2)

        ' 8 = Normal priority, 13 = High priority
        processDescriptions.Add(New ProcessDescription2 With {
                                    .ProcessName = "explorer",
                                    .Description = "Windows Explorer",
                                    .Priority = 8})
        processDescriptions.Add(New ProcessDescription2 With {
                                    .ProcessName = "winlogon",
                                    .Description = "Windows Logon",
                                    .Priority = 13})
        processDescriptions.Add(New ProcessDescription2 With {
                                    .ProcessName = "cmd",
                                    .Description = "Command Window",
                                    .Priority = 8})
        processDescriptions.Add(New ProcessDescription2 With {
                                    .ProcessName = "iexplore",
                                    .Description = "Internet Explorer",
                                    .Priority = 8})

        Dim processes = From proc In Process.GetProcesses
                        Join desc In processDescriptions
                          On proc.ProcessName Equals desc.ProcessName And
                             proc.BasePriority Equals desc.Priority
                        Select proc.ProcessName, proc.Id, desc.Description,
                               desc.Priority

        For Each proc In processes
            Console.WriteLine("{0} ({1}), {2}, Priority = {3}",
                              proc.ProcessName,
                              proc.Id,
                              proc.Description,
                              proc.Priority)
        Next
    End Sub

End Class

Public Class ProcessDescription2
    Public ProcessName As String
    Public Description As String
    Public Priority As Integer
End Class

Im Beispiel wird die Ausgabe ähnlich wie folgt ausgegeben:

winlogon (968), Windows Logon, Priority = 13

cmd (700), Command Window, Priority = 8

explorer (2424), File Explorer, Priority = 8

Siehe auch

  • Last updated on