Using Variance in Delegates (Visual Basic) (Verwenden von Varianz in Delegaten (Visual Basic))

Wenn Sie einer Delegaten eine Methode zuweisen, bieten Kovarianz und Kontravarianz Flexibilität bei der Anpassung eines Delegattyps an eine Methodensignatur. Kovarianz lässt die Verfügung einer Methode über einen Rückgabetyp zu, der stärker abgeleitet ist als der im Delegat definierte Typ. Contravarianz erlaubt eine Methode mit Parametertypen, die weniger abgeleitet sind als diejenigen im Delegatentyp.

Beispiel 1: Kovarianz

BESCHREIBUNG

In diesem Beispiel wird veranschaulicht, wie Delegaten mit Methoden verwendet werden können, die über Rückgabetypen verfügen, die von den Rückgabetypen in der Delegatsignatur abgeleitet sind. Der von DogsHandler zurückgegebene Datentyp ist vom Typ Dogs, der von dem Typ Mammals abgeleitet ist, der im Delegaten definiert ist.

Programmcode

Class Mammals
End Class

Class Dogs
    Inherits Mammals
End Class
Class Test
    Public Delegate Function HandlerMethod() As Mammals
    Public Shared Function MammalsHandler() As Mammals
        Return Nothing
    End Function
    Public Shared Function DogsHandler() As Dogs
        Return Nothing
    End Function
    Sub Test()
        Dim handlerMammals As HandlerMethod = AddressOf MammalsHandler
        ' Covariance enables this assignment.
        Dim handlerDogs As HandlerMethod = AddressOf DogsHandler
    End Sub
End Class

Beispiel 2: Kontravarianz

BESCHREIBUNG

In diesem Beispiel wird veranschaulicht, wie Stellvertretungen mit Methoden verwendet werden können, deren Typen Basistypen des Stellvertretungssignaturparametertyps sind. Mit kontravarianz können Sie einen Ereignishandler anstelle separater Handler verwenden. Im folgenden Beispiel werden zwei Stellvertretungen verwendet:

• Ein KeyEventHandler Delegat, der die Signatur des Button.KeyDown-Ereignisses definiert. Die Signatur lautet:

  Public Delegate Sub KeyEventHandler(sender As Object, e As KeyEventArgs)
  

• Ein MouseEventHandler Delegat, der die Signatur des Button.MouseClick-Ereignisses definiert. Die Signatur lautet:

  Public Delegate Sub MouseEventHandler(sender As Object, e As MouseEventArgs)
  

Das Beispiel definiert einen Ereignishandler mit einem EventArgs Parameter und verwendet ihn, um sowohl die Ereignisse Button.KeyDown als auch die Button.MouseClick Ereignisse zu behandeln. Es kann dies tun, weil EventArgs ein Basistyp sowohl von KeyEventArgs als auch von MouseEventArgs ist.

Programmcode

' Event handler that accepts a parameter of the EventArgs type.
Private Sub MultiHandler(ByVal sender As Object,
                         ByVal e As System.EventArgs)
    Label1.Text = DateTime.Now
End Sub

Private Sub Form1_Load(ByVal sender As System.Object,
    ByVal e As System.EventArgs) Handles MyBase.Load

    ' You can use a method that has an EventArgs parameter,
    ' although the event expects the KeyEventArgs parameter.
    AddHandler Button1.KeyDown, AddressOf MultiHandler

    ' You can use the same method
    ' for the event that expects the MouseEventArgs parameter.
    AddHandler Button1.MouseClick, AddressOf MultiHandler
End Sub

Siehe auch

• Variance in Delegates (Visual Basic) (Varianz in Delegaten (Visual Basic))
• Using Variance for Func and Action Generic Delegates (Visual Basic) (Verwenden von Varianz für die generischen Delegaten Func und Action (Visual Basic))