コンテナーの分析情報のレガシ認証

コンテナーの分析情報の既定値は、クラスターのマネージド ID を使用して Azure Monitor にデータを送信する監視エージェントがあるマネージド ID認証です。 レガシ証明書ベースのローカル認証が置き換えられ、クラスターに Monitoring Metrics Publisher ロールを追加する必要がなくなります。

この記事では、レガシ認証方法を使用してコンテナーの分析情報を有効にした場合にマネージド ID 認証に移行する方法と、その要件がある場合にレガシ認証を有効にする方法について説明します。

レガシ認証を使用してクラスターを検索する

次のクエリは、コンテナー分析情報でレガシ認証を使用するクラスターを一覧表示します。 クエリを実行するには、Resource Graph エクスプローラーを使用します。 クエリは、既存の Azure portal スコープ内で実行されます。 ポータルでスコープを設定して Azure Resource Graph クエリを実行する方法の詳細については、「クイックスタート: Azure portal を使用して Resource Graph クエリを実行する」を参照してください。

AKS クラスターのクエリ

resources        
| where type =~ 'Microsoft.ContainerService/managedClusters'       
| project id, name, aksproperties = parse_json(tolower(properties)), ___location, identity        
| extend isEnabled = aksproperties.addonprofiles.omsagent.enabled         
| extend workspaceResourceId = iif(isEnabled == true, aksproperties.addonprofiles.omsagent.config.loganalyticsworkspaceresourceid, '')        
| extend useAADAuth  = aksproperties.addonprofiles.omsagent.config.useaadauth  
| where isEnabled =~ "true" and useAADAuth != true 
| extend parts = split(tostring(id), "/")
| extend subscriptionId = parts[2], AKSClusterName = parts[-1], resourceGroupName = parts[4] 
| project AKSClusterName, resourceGroupName, subscriptionId, ___location, AKSClusterId = tolower(id), workspaceResourceId 

Arc を使用してオンプレミス クラスター、つまり、クラスターのクエリを実行します。

KubernetesConfigurationResources          
| where type =~ "Microsoft.KubernetesConfiguration/extensions"           
| extend properties = parse_json(tolower(properties))           
| extend extensionType = properties.extensiontype            
| where extensionType in~ ('microsoft.azuremonitor.containers')           
| extend omsagentUseAADAuth = tostring(properties.configurationsettings.["omsagent.useaadauth"])           
| extend amalogsUseAADAuth = tostring(properties.configurationsettings.["amalogs.useaadauth"])            
| extend useAADAuth = iff(omsagentUseAADAuth == 'true' or amalogsUseAADAuth == 'true', 'true', 'false')            
| extend workspaceResourceId = tostring(properties.configurationsettings.loganalyticsworkspaceresourceid)            
| extend resourceId = tolower(split(id, "/providers/Microsoft.KubernetesConfiguration")[0]) 
| where useAADAuth != "true"
| extend parts = split(tostring(resourceId), "/")
| extend subscriptionId = parts[2], ClusterName = parts[-1], ResourceGroupName = parts[4] 
| project ClusterName, ResourceGroupName,resourceId, subscriptionId, workspaceResourceId

マネージド ID 認証に移行する

マネージド ID 認証が使用可能になる前にコンテナーの分析情報を有効にした場合は、次の方法を使用してクラスターを移行できます。

レガシ認証を有効にする

レガシ認証が必要な場合は、「コンテナー分析情報を有効にする」を参照してください。コンテナー分析情報を有効にするためのさまざまなオプションの例があります。

次のステップ

エージェントのアップグレード中に問題が発生した場合は、トラブルシューティング ガイドを参照してください。