柔軟な型

柔軟な型注釈は、パラメーター、変数、または値に、クラスまたはインターフェイスのオブジェクト指向階層での位置によって互換性が決定される、指定した型と互換性のある型があることを示します。 柔軟な型は、型階層の上位の型への自動変換が行われなくても、階層内の任意の型またはインターフェイスを実装する任意の型で機能を操作できるようにする場合に特に便利です。

構文

#type

注釈

前の構文では、 型 は基本型またはインターフェイスを表します。

フレキシブル型は、許可される型を基本型またはインターフェイス型と互換性のある型に制限する制約を持つジェネリック型と同等です。 つまり、次の 2 行のコードは同等です。

#SomeType

'T when 'T :> SomeType

柔軟な型は、いくつかの種類の状況で役立ちます。 たとえば、上位の関数 (関数を引数として受け取る関数) がある場合、多くの場合、関数が柔軟な型を返すと便利です。 次の例では、 iterate2 でシーケンス引数を持つ柔軟な型を使用すると、上位の関数でシーケンス、配列、リスト、およびその他の列挙可能な型を生成する関数を操作できます。

次の 2 つの関数について考えてみましょう。そのうちの 1 つはシーケンスを返し、もう 1 つはフレキシブル型を返します。

let iterate1 (f : unit -> seq<int>) =
    for e in f() do printfn "%d" e
let iterate2 (f : unit -> #seq<int>) =
    for e in f() do printfn "%d" e

// Passing a function that takes a list requires a cast.
iterate1 (fun () -> [1] :> seq<int>)

// Passing a function that takes a list to the version that specifies a
// flexible type as the return value is OK as is.
iterate2 (fun () -> [1])

別の例として、 Seq.concat ライブラリ関数を考えてみましょう。

val concat: sequences:seq<#seq<'T>> -> seq<'T>

この関数には、次の列挙可能なシーケンスのいずれかを渡すことができます。

• リストの一覧
• 配列の一覧
• リストの配列
• シーケンスの配列
• 列挙可能なシーケンスのその他の組み合わせ

次のコードでは、 Seq.concat を使用して、柔軟な型を使用してサポートできるシナリオを示します。

let list1 = [1;2;3]
let list2 = [4;5;6]
let list3 = [7;8;9]

let concat1 = Seq.concat [ list1; list2; list3]
printfn "%A" concat1

let array1 = [|1;2;3|]
let array2 = [|4;5;6|]
let array3 = [|7;8;9|]

let concat2 = Seq.concat [ array1; array2; array3 ]
printfn "%A" concat2

let concat3 = Seq.concat [| list1; list2; list3 |]
printfn "%A" concat3

let concat4 = Seq.concat [| array1; array2; array3 |]
printfn "%A" concat4

let seq1 = { 1 .. 3 }
let seq2 = { 4 .. 6 }
let seq3 = { 7 .. 9 }

let concat5 = Seq.concat [| seq1; seq2; seq3 |]

printfn "%A" concat5

出力は次のとおりです。

seq [1; 2; 3; 4; ...]
seq [1; 2; 3; 4; ...]
seq [1; 2; 3; 4; ...]
seq [1; 2; 3; 4; ...]
seq [1; 2; 3; 4; ...]

F# では、他のオブジェクト指向言語と同様に、インターフェイスを実装する派生型または型が基本型またはインターフェイス型に自動的に変換されるコンテキストがあります。 これらの自動変換は直接引数で行われますが、型が下位の位置にある場合、関数型の戻り値の型などのより複雑な型の一部として、または型引数として発生しません。 したがって、柔軟な型表記は、適用する型がより複雑な型の一部である場合に主に役立ちます。

こちらも参照ください

• F# 言語リファレンス
• ジェネリック