Using ステートメント (Visual Basic)

Using ブロックの先頭を宣言し、必要に応じてブロックが制御するシステム リソースを取得します。

構文

Using { resourcelist | resourceexpression }
    [ statements ]
End Using

部品

resourcelistパーツの各リソースには、次の構文と部分があります。

resourcename As New resourcetype [ ( [ arglist ] ) ]

-又は-

resourcename As resourcetype = resourceexpression

resourcelist パーツ

注釈

コードで、ファイル ハンドル、COM ラッパー、SQL 接続などのアンマネージ リソースが必要な場合があります。 Using ブロックは、コードが終了したときに、このようなリソースを 1 つ以上破棄することを保証します。 これにより、他のコードで使用できるようになります。

マネージド リソースは.NET Framework ガベージ コレクター (GC) によって破棄され、追加のコーディングは行いません。 マネージド リソースに Using ブロックは必要ありません。 ただし、ガベージ コレクターを待機するのではなく、 Using ブロックを使用してマネージド リソースを強制的に破棄することはできます。

Using ブロックには、取得、使用、破棄の 3 つの部分があります。

• 取得 とは、変数を作成し、それを初期化してシステム リソースを参照することを意味します。 Using ステートメントでは、1 つ以上のリソースを取得することも、ブロックを入力して Using ステートメントに指定する前に、1 つのリソースを正確に取得することもできます。 resourceexpressionを指定する場合は、Using ステートメントに制御を渡す前にリソースを取得する必要があります。

• 使用状況 とは、リソースにアクセスし、それらに対してアクションを実行することを意味します。 UsingとEnd Usingの間のステートメントは、リソースの使用状況を表します。

• 破棄とは、resourcename内のオブジェクトに対してDispose メソッドを呼び出すことです。 これにより、オブジェクトはリソースをクリーンに終了できます。 End Using ステートメントは、Using ブロックの制御下にあるリソースを破棄します。

行動

Using ブロックは、Try...Finally 構築のように動作し、Try ブロックはリソースを使用し、Finally ブロックはそれらを破棄します。 このため、 Using ブロックは、ブロックを終了する方法に関係なく、リソースの破棄を保証します。 これは、 StackOverflowExceptionを除き、ハンドルされない例外の場合でも当てはまります。

Using ステートメントによって取得されるすべてのリソース変数のスコープは、Using ブロックに制限されます。

Using ステートメントで複数のシステム リソースを指定した場合、Usingブロックを入れ子にした場合と同じ効果が得られます。

resourcenameがNothingされている場合、Disposeの呼び出しは行われず、例外はスローされません。

Using ブロック内での構造化例外処理

Using ブロック内で発生する可能性のある例外を処理する必要がある場合は、完全なTry...Finally構築を追加できます。 Using ステートメントがリソースの取得に失敗した場合に対処する必要がある場合は、resourcenameがNothingされているかどうかをテストできます。

Using ブロックではなく構造化例外処理

リソースの取得を細かく制御する必要がある場合や、 Finally ブロックに追加のコードが必要な場合は、 Using ブロックを Try...Finally 構築として書き換えることができます。 次の例は、resourceの取得と破棄に相当するスケルトン TryとUsing構造を示しています。

Using resource As New resourceType
    ' Insert code to work with resource.
End Using

' For the acquisition and disposal of resource, the following  
' Try construction is equivalent to the Using block.
Dim resource As New resourceType
Try
    ' Insert code to work with resource.
Finally
    If resource IsNot Nothing Then
        resource.Dispose()
    End If
End Try

例

次の例では、log.txt という名前のファイルを作成し、2 行のテキストをファイルに書き込みます。 この例では、同じファイルを読み取り、テキスト行を表示します。

TextWriterクラスとTextReader クラスはIDisposable インターフェイスを実装するため、コードはUsingステートメントを使用して、書き込みおよび読み取り操作後にファイルが正しく閉じられるようにすることができます。

Private Sub WriteFile()
    Using writer As System.IO.TextWriter = System.IO.File.CreateText("log.txt")
        writer.WriteLine("This is line one.")
        writer.WriteLine("This is line two.")
    End Using
End Sub

Private Sub ReadFile()
    Using reader As System.IO.TextReader = System.IO.File.OpenText("log.txt")
        Dim line As String

        line = reader.ReadLine()
        Do Until line Is Nothing
            Console.WriteLine(line)
            line = reader.ReadLine()
        Loop
    End Using
End Sub

こちらも参照ください

• IDisposable
• Try...Catch...Finally ステートメント
• 方法: システム リソースを破棄する