Let statement

Applies to: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

A let statement is used to set a variable name equal to an expression or a function, or to create views.

let ステートメントは、次の場合に役立ちます。

• 複雑な式を、それぞれが変数によって表される複数の部分に分割する。
• 読みやすくするため、クエリ本体の外部で定数を定義する。
• 変数を一度定義し、1 つのクエリ内で複数回それを使用する。

入れ子になったステートメントなど、変数が前に別の値を表していた場合は、最も内側の let ステートメントが適用されます。

1 つのクエリ内での let ステートメントの複数使用を最適化するには、「名前付き式を使用するクエリを最適化する」を参照してください。

構文: スカラーまたは表形式の式

let Name=Expression

Learn more about syntax conventions.

Parameters

構文: ビューまたは関数

let Name= [view] ([ Parameters ]){FunctionBody}

Learn more about syntax conventions.

Parameters

Examples

クエリの例は、演算子、ステートメント、または関数の構文と使用例を示しています。

スカラー値を定義する

次の例では、スカラー式のステートメントを使用しています。

let threshold = 50;
let region = "West";
datatable(Name:string, Score:int, Region:string)
[
    "Alice", 45, "West",
    "Bob", 60, "East",
    "Charlie", 55, "West",
    "Dana", 70, "North"
]
| where Score > threshold and Region == region

Output

表形式の式を定義する

次の例では、some number の概念を使用して名前 ['name'] をバインドした後、表形式の式のステートメントでそれを使用します。

let ['some number'] = 20;
range y from 0 to ['some number'] step 5

Output

スカラー計算を使用してユーザー定義関数を作成する

この例では、スカラー計算の引数で let ステートメントを使用します。 2 つの数値を乗算する関数 MultiplyByN をクエリで定義します。

let MultiplyByN = (val:long, n:long) { val * n };
range x from 1 to 5 step 1 
| extend result = MultiplyByN(x, 5)

Output

入力をトリミングするユーザー定義関数を作成する

次の例では、入力の先頭と末尾から 1 を削除します。

let TrimOnes = (s:string) { trim("1", s) };
range x from 10 to 15 step 1 
| extend result = TrimOnes(tostring(x))

Output

複数の let ステートメントを使用する

この例では、2 つの let ステートメントを定義し、一方のステートメント (foo2) で他方 (foo1) を使用します。

let foo1 = (_start:long, _end:long, _step:long) { range x from _start to _end step _step};
let foo2 = (_step:long) { foo1(1, 100, _step)};
foo2(2) | count

Output

ビューまたは仮想テーブルを作成する

この例では、let ステートメントを使用して、view または仮想テーブルを作成する方法を示します。

let Range10 = view () { range MyColumn from 1 to 10 step 1 };
let Range20 = view () { range MyColumn from 1 to 20 step 1 };
search MyColumn == 5

Output

materialize 関数を使用する

materialize() 関数を使用すると、クエリの実行時に、サブクエリの結果をキャッシュすることができます。 materialize() 関数を使用すると、データがキャッシュされ、その後の結果の呼び出しではキャッシュされたデータが使用されます。

let TotalEventsbyLocation = StormEvents
| summarize TotalCount = count() by Location = BeginLocation;
let materializedScope = StormEvents
| summarize by EventType, Location = EndLocation;
let cachedResult = materialize(materializedScope);
cachedResult
| project EventType, Location
| join kind = inner
(
    cachedResult
    | project EventType, Location
)
on EventType
| where Location != ""
| summarize EventCount = count() by Location
| join kind = inner
    TotalEventsbyLocation
on $left.Location == $right.Location
| project Location, EventCount, TotalCount, Percentage = EventCount * 100.0 / TotalCount

Output

入れ子になった let ステートメントの使用

ユーザー定義関数式の中も含めて、入れ子になった let ステートメントを使用できます。 let ステートメントと引数は、関数本体の現在のスコープと内部のスコープの両方に適用されます。

let start_time = ago(5h); 
let end_time = start_time + 2h; 
T | where Time > start_time and Time < end_time | ...

スキーマを使用した表形式の引数

次の例では、表パラメーター T に State 型の列 string が必要であることを指定しています。 表 T には他の列も含めることができますが、宣言されていないため、関数 StateState で参照することはできません。

let StateState=(T: (State: string)) { T | extend s_s=strcat(State, State) };
StormEvents
| invoke StateState()
| project State, s_s

Output

ワイルドカードを使用した表形式の引数

表パラメーター T には任意のスキーマを指定でき、関数 CountRecordsInTable は機能します。

let CountRecordsInTable=(T: (*)) { T | count };
StormEvents | invoke CountRecordsInTable()

Output