range operator

Applies to: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

値が含まれる 1 列のテーブルを生成します。

Syntax

range columnNamefromstarttostopstepstep

Learn more about syntax conventions.

Parameters

Returns

A table with a single column called columnName, whose values are start, start+step, ... up to and until stop.

Examples

このセクションの例では、構文を使用して作業を開始する方法を示します。

過去 7 日間の範囲

次の例では、過去 7 日間に 1 日に 1 回、現在のタイム スタンプのエントリを含むテーブルを作成します。

range LastWeek from ago(7d) to now() step 1d

Output

異なる停止時間を組み合わせる

次の例は、union 演算子を使用して、複数の停止時間を使用するように範囲を拡張する方法を示しています。

let Range1 = range Time from datetime(2024-01-01) to datetime(2024-01-05) step 1d;
let Range2 = range Time from datetime(2024-01-06) to datetime(2024-01-10) step 1d;
union Range1, Range2
| order by Time asc

Output

パラメーターを使用した範囲

次の例では、パラメーターと共に range 演算子を使用する方法を示します。この演算子は、テーブルとして拡張および使用されます。

let toUnixTime = (dt:datetime) 
{ 
    (dt - datetime(1970-01-01)) / 1s 
};
let MyMonthStart = startofmonth(now()); //Start of month
let StepBy = 4.534h; //Supported timespans
let nn = 64000; // Row Count parametrized
let MyTimeline = range MyMonthHour from MyMonthStart to now() step StepBy
| extend MyMonthHourinUnixTime = toUnixTime(MyMonthHour), DateOnly = bin(MyMonthHour,1d), TimeOnly = MyMonthHour - bin(MyMonthHour,1d)
; MyTimeline | order by MyMonthHour asc | take nn

Output

Incremented steps

次の例では、型が Stepslong という 1 つの列を持つテーブルを作成し、1 から 8 の値を 3 ずつインクリメントします。

range Steps from 1 to 8 step 3

Output

時間範囲のトレース

次の例は、range 演算子を使用して、ソース データに値がないゼロを導入するために使用されるディメンション テーブルを作成する方法を示しています。 過去 4 時間のタイムスタンプを取得し、1 分間隔ごとにトレースをカウントします。 特定の間隔のトレースがない場合、カウントは 0 になります。

range TIMESTAMP from ago(4h) to now() step 1m
| join kind=fullouter
  (Traces
      | where TIMESTAMP > ago(4h)
      | summarize Count=count() by bin(TIMESTAMP, 1m)
  ) on TIMESTAMP
| project Count=iff(isnull(Count), 0, Count), TIMESTAMP
| render timechart