Let statement

Applies to: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

A let statement is used to set a variable name equal to an expression or a function, or to create views.

let 문은 다음에 유용합니다.

• 복잡한 식을 각각 변수로 나타내는 여러 부분으로 나타낸다.
• 가독성을 위해 쿼리 본문 외부의 상수 정의
• 변수를 한 번 정의하고 쿼리 내에서 여러 번 사용합니다.

변수가 이전에 다른 값을 나타내는 경우(예: 중첩된 문에서) 가장 let 안쪽 문이 적용됩니다.

단일 쿼리 내에서 문의 여러 사용을 let 최적화하려면 명명된 식을 사용하는 쿼리 최적화를 참조 하세요.

구문: 스칼라 또는 테이블 형식 식

let Name=Expression

Learn more about syntax conventions.

Parameters

구문: 보기 또는 함수

let Name= [view] ([ Parameters ]){FunctionBody}

Learn more about syntax conventions.

Parameters

Examples

쿼리 예제는 연산자, 문 또는 함수의 구문 및 사용 예제를 보여 줍니다.

스칼라 값 정의

다음 예제에서는 스칼라 식 문을 사용합니다.

let threshold = 50;
let region = "West";
datatable(Name:string, Score:int, Region:string)
[
    "Alice", 45, "West",
    "Bob", 60, "East",
    "Charlie", 55, "West",
    "Dana", 70, "North"
]
| where Score > threshold and Region == region

Output

테이블 형식 식 정의

다음 예제에서는 표기법을 사용하여 some number 이름을 ['name'] 바인딩한 다음 테이블 형식 식 문에서 사용합니다.

let ['some number'] = 20;
range y from 0 to ['some number'] step 5

Output

스칼라 계산을 사용하여 사용자 정의 함수 만들기

이 예제에서는 스칼라 계산에 대한 인수와 함께 let 문을 사용합니다. 쿼리는 두 숫자를 곱하는 함수 MultiplyByN 를 정의합니다.

let MultiplyByN = (val:long, n:long) { val * n };
range x from 1 to 5 step 1 
| extend result = MultiplyByN(x, 5)

Output

입력을 자르는 사용자 정의 함수 만들기

다음 예제에서는 입력에서 선행 및 후행을 제거합니다.

let TrimOnes = (s:string) { trim("1", s) };
range x from 10 to 15 step 1 
| extend result = TrimOnes(tostring(x))

Output

다중 let 문 사용

이 예제에서는 한 문()이 다른foo2 문(foo1)을 사용하는 두 개의 let 문을 정의합니다.

let foo1 = (_start:long, _end:long, _step:long) { range x from _start to _end step _step};
let foo2 = (_step:long) { foo1(1, 100, _step)};
foo2(2) | count

Output

뷰 또는 가상 테이블 만들기

이 예제에서는 let 문을 사용하여 또는 가상 테이블을view 방법을 보여줍니다.

let Range10 = view () { range MyColumn from 1 to 10 step 1 };
let Range20 = view () { range MyColumn from 1 to 20 step 1 };
search MyColumn == 5

Output

구체화 함수 사용

materialize() 함수를 사용하면 쿼리 실행 시간 동안 하위 쿼리 결과를 캐시할 수 있습니다. 함수를 materialize() 사용하면 데이터가 캐시되고, 이후의 결과 호출에서 캐시된 데이터를 사용합니다.

let TotalEventsbyLocation = StormEvents
| summarize TotalCount = count() by Location = BeginLocation;
let materializedScope = StormEvents
| summarize by EventType, Location = EndLocation;
let cachedResult = materialize(materializedScope);
cachedResult
| project EventType, Location
| join kind = inner
(
    cachedResult
    | project EventType, Location
)
on EventType
| where Location != ""
| summarize EventCount = count() by Location
| join kind = inner
    TotalEventsbyLocation
on $left.Location == $right.Location
| project Location, EventCount, TotalCount, Percentage = EventCount * 100.0 / TotalCount

Output

중첩된 let 문 사용

사용자 정의 함수 식 내를 포함하여 중첩된 let 문이 허용됩니다. Let 문과 인수는 함수 본문의 현재 범위와 내부 범위 모두에서 적용됩니다.

let start_time = ago(5h); 
let end_time = start_time + 2h; 
T | where Time > start_time and Time < end_time | ...

스키마가 있는 테이블 형식 인수

다음 예제에서는 테이블 매개 변수 T 에 형식State의 열 string 이 있어야 하며 테이블에 T 는 다른 열도 포함될 수 있지만 선언되지 않았기 때문에 함수 StateState 에서 참조할 수 없습니다.

let StateState=(T: (State: string)) { T | extend s_s=strcat(State, State) };
StormEvents
| invoke StateState()
| project State, s_s

Output

와일드카드가 있는 테이블 형식 인수

테이블 매개 변수 T 에는 스키마가 있을 수 있으며 함수 CountRecordsInTable 가 작동합니다.

let CountRecordsInTable=(T: (*)) { T | count };
StormEvents | invoke CountRecordsInTable()

Output