Passo a passo: manipulando arquivos usando métodos do .NET Framework (Visual Basic)

Este passo a passo demonstra como abrir e ler um arquivo usando a StreamReader classe, verificar se um arquivo está sendo acessado, pesquisar uma cadeia de caracteres dentro de um arquivo lido com uma instância da StreamReader classe e gravar em um arquivo usando a StreamWriter classe.

Criando o aplicativo

Inicie o Visual Studio e inicie o projeto criando um formulário que o usuário pode usar para gravar no arquivo designado.

Para criar o projeto

1. No menu Arquivo, selecione Novo Projeto.

2. No painel Novo Projeto , clique em Aplicativo do Windows.

3. Na caixa Nome , digite MyDiary e clique em OK.

   O Visual Studio adiciona o projeto ao Gerenciador de Soluções e o Designer de Formulários do Windows é aberto.

4. Adicione os controles na tabela a seguir ao formulário e defina os valores correspondentes para suas propriedades.

Gravando no arquivo

Para adicionar a capacidade de gravar em um arquivo por meio do aplicativo, use a StreamWriter classe. StreamWriter é projetado para saída de caractere em uma codificação específica, enquanto a Stream classe foi projetada para entrada e saída de bytes. Use StreamWriter para escrever linhas de informações em um arquivo de texto padrão. Para obter mais informações sobre a StreamWriter classe, consulte StreamWriter.

Para adicionar a funcionalidade de gravação

1. No menu Exibir , escolha Código para abrir o Editor de Código.

2. Como o aplicativo faz referência ao System.IO namespace, adicione as instruções a seguir no início do código, antes da declaração de classe do formulário, que começa Public Class Form1.

   Imports System.IO
   

   Antes de gravar no arquivo, você deve criar uma instância de uma StreamWriter classe.

3. No menu Exibir , escolha Designer para retornar ao Designer de Formulários do Windows. Clique duas vezes no Submit botão para criar um Click manipulador de eventos para o botão e adicione o código a seguir.

   Dim fw As StreamWriter
   

1. Para gravar no arquivo, use o Write método da StreamWriter classe. Adicione o código a seguir diretamente após Dim fw As StreamWriter. Você não precisa se preocupar que uma exceção será gerada se o arquivo não for encontrado, pois ele será criado se ele ainda não existir.

   Dim ReadString As String
   Try
       'Pass the file path and name to the StreamWriter constructor.
       'Indicate that Append is True, so file will not be overwritten.
       fw = New StreamWriter("C:\MyDiary.txt", True)
       ReadString = Entry.Text
       fw.WriteLine(ReadString)
   Finally
       'Close the file.
       fw.Close()
   End Try
   

2. Verifique se o usuário não pode enviar uma entrada em branco adicionando o código a seguir diretamente depois Dim ReadString As String.

   If (Entry.Text = "" Or Entry.Text = "Please enter something.") Then
       Entry.Text = "Please enter something."
       Return
   End If
   

3. Como este é um diário, o usuário desejará atribuir uma data a cada entrada. Insira o código a seguir após fw = New StreamWriter("C:\MyDiary.txt", True) para definir a variável Today como a data atual.

   Dim Today As DateTime
   Today = Now
   fw.Write(CStr(Today))
   fw.Write(ControlChars.CrLf)
   

4. Por fim, anexe o código para limpar o TextBox. Adicione o seguinte código ao evento Clear do botão Click.

   Entry.Text = ""
   

Adicionando recursos de exibição ao Diário

Nesta seção, você adicionará um recurso que exibe a entrada mais recente no DisplayEntryTextBox. Você também pode adicionar um ComboBox que exibe várias entradas e do qual um usuário pode selecionar uma entrada para exibir no DisplayEntryTextBox. Uma instância da classe StreamReader lê de MyDiary.txt. Assim como a StreamWriter classe, StreamReader destina-se ao uso com arquivos de texto.

Para esta seção do passo a passo, adicione os controles na tabela a seguir ao formulário e defina os valores correspondentes para suas propriedades.

Para popular a caixa de combinação

1. O PickEntriesComboBox é usado para exibir as datas em que um usuário envia cada entrada, para que o usuário possa selecionar uma entrada de uma data específica. Crie um Click manipulador de eventos ao GetEntries botão e adicione o código a seguir.

   Dim fr As StreamReader = Nothing
   Dim FileString As String
   FileString = ""
   Try
       fr = New System.IO.StreamReader("C:\MyDiary.txt")
       PickEntries.Items.Clear()
       PickEntries.Enabled = True
       Do
           FileString = fr.ReadLine
           If IsDate(FileString) Then
               PickEntries.Items.Add(FileString)
           End If
       Loop Until (FileString Is Nothing)
   Finally
       If fr IsNot Nothing Then
           fr.Close()
       End If
   End Try
   PickEntries.Enabled = True
   

2. Para testar seu código, pressione F5 para compilar o aplicativo e clique em Obter Entradas. Clique na seta do menu suspenso no ComboBox para exibir as datas de entrada.

Para escolher e exibir entradas individuais

1. Crie um Click manipulador de eventos para o Display botão e adicione o código a seguir.

   Dim fr As StreamReader
   Dim ReadString As String
   'Make sure ReadString begins empty.
   ReadString = ""
   Dim FileString As String
   fr = New StreamReader("C:\MyDiary.txt")
   'If no entry has been selected, show the whole file.
   If PickEntries.Enabled = False Or PickEntries.SelectedText Is Nothing Then
       Do
           'Read a line from the file into FileString.
           FileString = fr.ReadLine
           'add it to ReadString
           ReadString = ReadString & ControlChars.CrLf & FileString
       Loop Until (FileString = Nothing)
   Else
       'An entry has been selected, find the line that matches.
       Do
   
           FileString = fr.ReadLine
       Loop Until FileString = CStr(PickEntries.SelectedItem)
       FileString = CStr(PickEntries.SelectedItem) & ControlChars.CrLf
       ReadString = FileString & fr.ReadLine
   
       'Read from the file until EOF or another Date is found.
       Do Until ((fr.Peek < 0) Or (IsDate(fr.ReadLine)))
           ReadString = ReadString & fr.ReadLine
       Loop
   End If
   fr.Close()
   DisplayEntry.Visible = True
   DisplayEntry.Text = ReadString
   

2. Para testar seu código, pressione F5 para compilar o aplicativo e envie uma entrada. Clique em Obter Entradas, selecione uma entrada e ComboBoxclique em Exibir. O conteúdo da entrada selecionada é exibido no DisplayEntryTextBox.

Habilitando os usuários a excluir ou modificar entradas

Por fim, você pode incluir funcionalidades adicionais que permitem que os usuários excluam ou modifiquem uma entrada usando DeleteEntry e EditEntry botões. Ambos os botões permanecem desabilitados, a menos que uma entrada seja exibida.

Adicione os controles na tabela a seguir ao formulário e defina os valores correspondentes para suas propriedades.

Para habilitar a exclusão e a modificação de entradas

1. Adicione o seguinte código ao evento Display do botão Click , depois de DisplayEntry.Text = ReadString.

   DeleteEntry.enabled = True
   

2. Crie um Click manipulador de eventos para o DeleteEntry botão e adicione o código a seguir.

   Dim fr As StreamReader
   Dim ReadString As String
   Dim WriteString As String
   Dim ConfirmDelete As MsgBoxResult
   fr = New StreamReader("C:\MyDiary.txt")
   ReadString = fr.ReadLine
   ' Read through the textfile
   Do Until (fr.Peek < 0)
       ReadString = ReadString & vbCrLf & fr.ReadLine
   Loop
   WriteString = Replace(ReadString, DisplayEntry.Text, "")
   fr.Close()
   ' Check to make sure the user wishes to delete the entry
   ConfirmDelete = MsgBox("Do you really wish to delete this entry?",
     MsgBoxStyle.OKCancel)
   If ConfirmDelete = MsgBoxResult.OK Then
       File.Delete("C:\MyDiary.txt")
       Dim fw As StreamWriter = File.CreateText("C:\MyDiary.txt")
       fw.WriteLine(WriteString)
       fw.Close()
       ' Reset controls on the form
       DisplayEntry.Text = ""
       PickEntries.Text = ""
       PickEntries.Items.Clear()
       PickEntries.Enabled = False
       DeleteEntry.Enabled = False
   End If
   

3. Quando um usuário exibe uma entrada, o EditEntry botão fica habilitado. Adicione o seguinte código ao evento Click do botão Display, depois de DisplayEntry.Text = ReadString.

   EditEntry.Enabled = True
   

4. Crie um Click manipulador de eventos para o EditEntry botão e adicione o código a seguir.

   Entry.Text = DisplayEntry.Text
   SubmitEdit.Enabled = True
   

5. Criar um Click manipulador de eventos para o SubmitEdit botão e adicionar o código a seguir

   Dim fr As StreamReader
   Dim ReadString As String
   Dim WriteString As String
   If Entry.Text = "" Then
       MsgBox("Use Delete to Delete an Entry")
       Return
   End If
   fr = New StreamReader("C:\MyDiary.txt")
   ReadString = fr.ReadLine
   Do Until (fr.Peek < 0)
       ReadString = ReadString & vbCrLf & fr.ReadLine
   Loop
   WriteString = Replace(ReadString, DisplayEntry.Text, Entry.Text)
   fr.Close()
   File.Delete("C:\MyDiary.txt")
   Dim fw As StreamWriter = File.CreateText("C:\MyDiary.txt")
   fw.WriteLine(WriteString)
   fw.Close()
   DisplayEntry.Text = Entry.Text
   Entry.Text = ""
   EditEntry.Enabled = False
   SubmitEdit.Enabled = False
   

Para testar seu código, pressione F5 para compilar o aplicativo. Clique em Obter Entradas, selecione uma entrada e clique em Exibir. A entrada é exibida no DisplayEntryTextBox. Clique em Editar Entrada. A entrada é exibida no EntryTextBox. Edite a entrada e clique em EntryTextBoxEnviar Editar. Abra o MyDiary.txt arquivo para confirmar sua correção. Agora, selecione uma entrada e clique em Excluir Entrada. Quando o MessageBox solicitar confirmação, clique em OK. Feche o aplicativo e abra MyDiary.txt para confirmar a exclusão.

Consulte também

• StreamReader
• StreamWriter
• Instruções passo a passo