Let statement

Applies to: ✅Microsoft Fabric✅Azure Data Explorer✅Azure Monitor✅Microsoft Sentinel

A let statement is used to set a variable name equal to an expression or a function, or to create views.

let declarações são úteis para:

• Dividir uma expressão complexa em várias partes, cada uma representada por uma variável.
• Definição de constantes fora do corpo da consulta para legibilidade.
• Definir uma variável uma vez e usá-la várias vezes dentro de uma consulta.

Se a variável representava anteriormente outro valor, por exemplo, em instruções aninhadas, aplica-se a instrução let mais interna.

Para otimizar vários usos da instrução let em uma única consulta, consulte Otimizar consultas que usam expressões nomeadas.

Sintaxe: Expressões escalares ou tabulares

let Name=Expression

Learn more about syntax conventions.

Parameters

Sintaxe: Vista ou função

let Name= [view] ([ Parameters ]){FunctionBody}

Learn more about syntax conventions.

Parameters

Examples

Os exemplos de consulta mostram a sintaxe e o uso de exemplo do operador, instrução ou função.

Definir valores escalares

O exemplo a seguir usa uma instrução de expressão escalar.

let threshold = 50;
let region = "West";
datatable(Name:string, Score:int, Region:string)
[
    "Alice", 45, "West",
    "Bob", 60, "East",
    "Charlie", 55, "West",
    "Dana", 70, "North"
]
| where Score > threshold and Region == region

Output

Definir expressões tabulares

O exemplo a seguir associa o nome some number usando a notação ['name'] e, em seguida, usa-o em uma instrução de expressão tabular.

let ['some number'] = 20;
range y from 0 to ['some number'] step 5

Output

Criar uma função definida pelo usuário com cálculo escalar

Este exemplo usa a instrução let com argumentos para cálculo escalar. A consulta define MultiplyByN de função para multiplicar dois números.

let MultiplyByN = (val:long, n:long) { val * n };
range x from 1 to 5 step 1 
| extend result = MultiplyByN(x, 5)

Output

Criar uma função definida pelo usuário que corta a entrada

O exemplo a seguir remove os à esquerda e à direita da entrada.

let TrimOnes = (s:string) { trim("1", s) };
range x from 10 to 15 step 1 
| extend result = TrimOnes(tostring(x))

Output

Usar várias instruções let

Este exemplo define duas instruções let em que uma instrução (foo2) usa outra (foo1).

let foo1 = (_start:long, _end:long, _step:long) { range x from _start to _end step _step};
let foo2 = (_step:long) { foo1(1, 100, _step)};
foo2(2) | count

Output

Criar uma vista ou tabela virtual

Este exemplo mostra como usar uma instrução let para criar uma tabela virtual ou view.

let Range10 = view () { range MyColumn from 1 to 10 step 1 };
let Range20 = view () { range MyColumn from 1 to 20 step 1 };
search MyColumn == 5

Output

Usar uma função de materialização

A função materialize() permite armazenar em cache os resultados da subconsulta durante o tempo de execução da consulta. Quando você usa a função materialize(), os dados são armazenados em cache e qualquer invocação subsequente do resultado usa dados armazenados em cache.

let TotalEventsbyLocation = StormEvents
| summarize TotalCount = count() by Location = BeginLocation;
let materializedScope = StormEvents
| summarize by EventType, Location = EndLocation;
let cachedResult = materialize(materializedScope);
cachedResult
| project EventType, Location
| join kind = inner
(
    cachedResult
    | project EventType, Location
)
on EventType
| where Location != ""
| summarize EventCount = count() by Location
| join kind = inner
    TotalEventsbyLocation
on $left.Location == $right.Location
| project Location, EventCount, TotalCount, Percentage = EventCount * 100.0 / TotalCount

Output

Usando instruções let aninhadas

Instruções let aninhadas são permitidas, inclusive dentro de uma expressão de função definida pelo usuário. Deixe que declarações e argumentos se apliquem tanto no escopo atual quanto no escopo interno do corpo da função.

let start_time = ago(5h); 
let end_time = start_time + 2h; 
T | where Time > start_time and Time < end_time | ...

Argumento tabular com esquema

O exemplo a seguir especifica que o parâmetro table T deve ter uma coluna State do tipo string. A tabela T pode incluir outras colunas também, mas elas não podem ser referenciadas na função StateState porque as não são declaradas.

let StateState=(T: (State: string)) { T | extend s_s=strcat(State, State) };
StormEvents
| invoke StateState()
| project State, s_s

Output

Argumento tabular com curinga

O parâmetro de tabela T pode ter qualquer esquema e a função CountRecordsInTable funcionará.

let CountRecordsInTable=(T: (*)) { T | count };
StormEvents | invoke CountRecordsInTable()

Output